Here are the corrections for the exercises of part 2:

Compute the sum of an array:

[Tape: zero data1 flag1 ... datan flagn sum zero]
>+++>+>+++++>+>++++>+>++++++>+>> initialize array
<< [  loop on the array
    - clear the current flag
    < [ 
        > >>[>>]< go to sum
        + add 1
        <[<<]< go back to the current data
        - remove 1
    ]
    >+ set the current flag
    << go to the next flag
]

Test if two strings are the same:

[Tape: zero nothing flag1 data1 ... flagn datan zero isgood]
>> + [ go on the first flag and start the reading loop
    - clear the flag so we can use this cell as a "else flag" cell
    > , read the current character in data
    ---------- [ test if it is not a newline
        <+ set the else flag
        >[>+<-] go out of the loop using the next flag which is currently 0
    ] >[<+>-] move back the value of data
    <++++++++++ add 10 to it (to restore its value)
    <[>>+<<-] if the else flag is set then we must set the next flag to continue the loop
    + set our current flag to 1 (its original value before we used it as a else flag)
    >> go to the next flag
]
< [-] > the last data is a newline and we want the last character to be a 0 (which is by convention the EOF character)
> + set the isgood flag do 1
<<<[<<]>> go on our first flag
[ loop on the array
    - clear the current flag to remember our position
    , since the current flag is 0 we can use it as a temporary cell to read the current character
    [>-<-] > [ if the characters are different
        >[>>]>[-] clear the isgood flag
        <<<[<<] go back to the array
        >[-] clear the cell to go out of the loop
    ]
    <+ set the current flag back to 1
    >> go on the next flag
]
we are now at the zero cell
++++++[>++++++++<-] add 48 to the isgood flag
>. print it
<++++++++++. print a newline

You may notice that when I know that a cell is set to 0 I use it as a temporary cell, but you have to double-check that this is not interfering with other techniques (eg. the array flag is set to 0 so I used it to store the current character, but I can’t go outside the array because the array flag is no more 0!)

Using a preprocessor

You might notice that programming in brainfuck is unpleasant because there are no variable names and we spend most of the time to think about “Well, which cell am I currently at?” and not to think about how to make the actual program.

That’s why I designed a language above Brainfuck that compiles to Brainfuck: SimpleBrainfuck. I won’t explain how the language works because it’s explained in the README, but I will show you the code of the second exercise in simplebrainfuck

#_ That's a macro written in C
#_ We use it like this: _add(5) is like +++++ and _add(-3) is like ---
#cmacro(add;
    int i;
    int nb = atoi(argv[0]);
    if(nb < 0) {
        for(i = 0; i < -nb; ++i) {
            push("-");
        }
    } else {
        for(i = 0; i < nb; ++i) {
            push("+");
        }
    }
)

#_ That's a macro that moves the value of the cell v1 to the cell v2
#macro(moveTo; v1; v2;;
    =v1; [=v2; + =v1; -]
)

#_ We define what is in our tape
#_ nflag stands for "next flag"
#variables(Begin; zero; nothing; firstFlag) #_ Before the array
#variables(Array; flag; data; nflag) #_ Inside the array
#variables(End; lastFlag; lastData; zero; isgood) #_ At the end of the array

#_ That's a macro to go at the end of the array when we are inside it
#macro(arrayToEnd;;
    =nflag; [>>] @End@zero;
)

#macro(endToArray;;
    =lastFlag; [<<] @Array@flag;
)

#_ Now the actual program
@Begin@zero; #_ This is how we tell to the preprocessor where we are
=firstFlag; #_ Go the cell named firstFlag. Here the preprocessor will insert ">>"
@Array@flag; + [
    -
    =data; ,
    _add(-10) [
        =flag; +
        _moveTo(data; nflag)
    ] _moveTo(nflag; data)
    =data; _add(10)
    _moveTo(flag; nflag)
    =flag; +
    =nflag;
]
< [-] >
@End@zero;
=isgood; +
=zero; <<[<<]>> @Array@flag;
[
    -
    , [=data; - =flag; -]
    =data; [
        _arrayToEnd() =isgood; [-]
        _endToArray()
        =data; [-]
    ]
    =flag; + >>
]
@End@zero;
_add(6) [=isgood; _add(8) =zero; -]
=isgood; .
=zero; _add(10) .

In my opinion, the above code is more readable that the first one in pure brainfuck. An other advantage is that if you discover that you need an other temporary cell somewhere, it will be a lot easier to change your tape scheme than in pure brainfuck.

Exercises

Exercise 1 (for the lazy writer): use SimpleBrainfuck to solve the previous exercises

Exercise 2: Now you learned enough things to craft big programs: why don’t you make a brainfuck interpreter in brainfuck? Given an input like code!in (! is a separator), you must run the code code with the input in

Here is a hint if you don’t know how to start: first, you read the code in an array, and then you have another array which will be the tape of the brainfuck program you interpret. Here is one solution if you want

Online resources

You can find several brainfuck programs on Esolang: algorithms and constants


Programming in Brainfuck: Part 2 — Arrays

Sat 28 May 2016 by TWal

Here are the corrections for the exercises of part 1:

Test if all characters are the same:

Tape: nb char otherchar temp flag
>+++++++[-<+++++++>] initialise nb to 49 ("1")
>> , [<+<+>>-] read in temp and  move to char and otherchar
< [ while otherchar
    >>+ set else flag
    <<< [->->+<<] check equality and keep the value in temp ...
read more

Programming in Brainfuck: Part 1 — Common patterns & conditions

Sun 24 August 2014 by TWal

Here are the corrections for the exercises of part 0:

To print “Brainfuck” followed by a new line, here is a solution:

The ASCII codes are: 66 114 97 105 110 102 117 99 107 10
++++++++++[>+++++++>+++++++++++>++++++++++>++++++++++>+<<<<<-]   setup the memory like this: 0 70 110 100 100 10
>----.>++++.>---.>+++++.<<----.>>---.<<+++++++.>++.++++++++.>>.  print "Brainfuck"

To ...

read more

Programming in Brainfuck: Part 0 — Introduction

Wed 20 August 2014 by TWal

I love brainfuck. I’m amazed by what we can do with only eight instructions. I learned almost everything I know on this language by myself because I didn’t find any tutorial that teach in-depth how to program in brainfuck.

I decided to change this and to make my ...

read more